SQLServerインスタンスをファイアウォールの例外として追加する

  • このエントリーをはてなブックマークに追加
  • このエントリーをはてなブックマークに追加

SQLServer2005:クライアントからの接続
で、SQLServerのインスタンスをファイアウォールの例外として追加しないとだけど、毎回追加するのは面倒だったからバッチファイルを作っておいた。

バッチ内容


@echo off
set C_FIREWALL=SQLServer2k5
set C_PATH1=C:\Program Files\Microsoft SQL Server\MSSQL.
set C_PATH2=\MSSQL\Binn\sqlservr.exe
set VAL_YN=
set VAL_NAME=
set VAL_NO=
echo;
echo ファイアウォールへSQLServerのインスタンスを例外として追加します。
echo ("Q"を入力するとキャンセルになります)
echo;
:INPUT_NAME
set /p VAL_NAME=インスタンス名:
if "%VAL_NAME%" == "" goto INPUT_NAME
if /I "%VAL_NAME%" == "Q" goto NO
:INPUT_NO
echo インスタンスのフォルダ番号(C:\Program Files\Microsoft SQL Server\MSSQL.?←これ)
set /p VAL_NO=:
if "%VAL_NO%" == "" goto INPUT_NO
if /I "%VAL_NO%" == "Q" goto NO
set VAL_PATH=%C_PATH1%%VAL_NO%%C_PATH2%
set VAL_FIREWALL=%C_FIREWALL%(%VAL_NAME%)
echo;
echo 設定内容の確認:
echo PROGRAM=%VAL_PATH%
echo NAME=%VAL_FIREWALL%
echo;
:INPUT_YN
set /p VAL_YN=実行してもよろしいですか?(Y/N):
if "%VAL_YN%" == "" goto INPUT_YN
if /I "%VAL_YN%" == "N" goto NO
if /I "%VAL_YN%" == "Y" goto YES
goto INPUT_YN
:YES
netsh firewall add allowedprogram program="%VAL_PATH%" name="%VAL_FIREWALL%"
rem echo netsh firewall add allowedprogram program="%VAL_PATH%" name="%VAL_FIREWALL%"
echo 登録されました。
PAUSE
goto :END
:NO
echo キャンセルされました。
:END

バッチファイル

Download

関連記事:

コメントを残す

メールアドレスが公開されることはありません。

*

This blog is kept spam free by WP-SpamFree.